AutoHotkey 初学者向导 by tidbit

1. 找到开始菜单或屏幕上的开始按钮，通常在左下角.
2. 点击程序或者所有程序.
3. 在列表中查找AutoHotkey.
4. 你会看到AutoHotkey Help File. 点击它.
5. 完成!

1. 去你的桌面.
2. 找到我的电脑或者计算机. 然后打开它.
3. 进入安装AutoHotkey的硬盘. 可能是C:\盘.
4. 在Program Files文件夹里找到AutoHotkey.
5. 查找AutoHotkey.chm 或者找一个名叫Autohotkey并带有黄色问号图标的文件.
6. 完成!

(想要获悉更详细的符号列表, 查看热键页)

!: 发送ALT键击. 例如, Send This is text!a 将发送按键序列 "This is text" 并接着按下 ALT+a. 注: 在某些程序中!A 和 !a会产生不同的效果. 这是因为 !A 表示按下 ALT+SHIFT+A 而 !a 表示按下 ALT+a. 如果不确定, 请使用小写字母.

+: 发送SHIFT键击. 例如，Send +abC 会发送文本 "AbC"，而 Send !+a 会按下 ALT+SHIFT+a.

^: 发送 CONTROL (Ctrl) 键击. 例如， Send ^!a 会按下 CTRL+ALT+a, 而 Send ^{Home} 则发送 CONTROL+HOME. 注: 在某些程序中 ^A 和 ^a 会产生不同的效果. 这是由于 ^A 按了 CONTROL+SHIFT+A 而 ^a 按了 CONTROL+a. 如果不确定, 请使用小写字母.

#: 发送 WIN 键击，因此 Send #e 会在按住 Windows 键时按下字母 "e".

; 当你创建热键时...
; 以下是错误的脚本
{LCtrl}::
   send, AutoHotkey
Return

; 以下是正确的脚本
LCtrl::
   send, AutoHotkey
Return

上面提到的大表展示了几乎所有AHK内置的特殊按键. 比如: {enter} 和 {space}.
有人常常认为文档中用花括号仅仅是为了好玩. 而实际上花括号是必须的. 它将告诉AutoHotkey {!} 表示 "感叹号" ，而不是要 "发送 Alt 键击". 所以要仔细查看send 页上的特殊按键列表，确保在合适的地方加上花括号.

; 注意{}中的!? 这是因为，如果没有{}, AHK 将
; 发送 ALT 键击.
send, This text has been typed{!}

; 跟上面的例子类似. AHK 将会打印单词 "enter" ...
; ... 如果enter没有加上{}的话.
send, Multiple enter lines have enter been sent. ; 错误
send, Multiple{enter}lines have{enter}been sent. ; 正确

; 不要在普通单词或普通字母上加上花括号.
send, {a}       ; 错误
send, {b}       ; 错误
send, {c}       ; 错误
send, {a}{b}{c} ; 错误
send, {abc}     ; 错误
send, abc       ; 正确

; 下面这个例子表示按下一个键的时候再按下另一个键（或多个键）.
; 如果其中一个方法不奏效，试试另外的方法.
send, ^s                     ; 都表示发送 CTRL+s 键击
send, {ctrl down}s{ctrl up}  ; 都表示发送 CTRL+s 键击
Send, {ctrl down}c{ctrl up}
Send, {b down}{b up}
Send, {TAB down}{TAB up}
Send, {Up down}  ; 按下向上键.
Sleep, 1000      ; 保持1秒.
Send, {Up up}    ; 然后松开向上键.

send,
(
Line 1
Line 2
Apples are a fruit.
)

• 通过下面3个方法使用 SendPlay命令: 1) 直接使用SendPlay命令; 2) 用 SendMode 切换到Play模式; 和/或 3) 将热字串发送键击的选项设置为SP（Sendplay）模式.
• 使用 SetKeyDelay 增加键击延时. 例如:
• SetKeyDelay, 0, 50
• SetKeyDelay, 150, 150, Play
• 使用 ControlSend 命令, 在其它Send模式都失效情况下使用，也许它能起作用.

; 运行一个程序. 注: 大部分的程序可能需要完整路径.
Run, %A_ProgramFiles%\Some_Program\Program.exe

; 打开一个网址
Run, http://ahkscript.org

; 一些程序并不需要完整路径，如Windows标准程序.
Run, Notepad.exe
Run, MsPaint.exe

; 使用 AHK 内置参数来打开"我的文档"
Run, %A_MyDocuments%

; 打开一些网页 
Run, http://ahkscript.org
Run, http://www.google.com

想深入了解更多信息和示例，可以点击:
Run 命令页.

有用的链接:
所用命令列表: commands/index.htm
所有内置函数列表: Functions.htm#BuiltIn

1. 你可以使用运算.
   -- SubStr(37*12, 1, 2)
   -- SubStr(A_Hour-12, 2)
2. 参数前后不需要加上百分号.
   -- SubStr(A_Now, 7, 2)
3. 函数可以嵌套另一个函数.
   -- SubStr(A_AHKPath, inStr(A_AHKPath, "AutoHotkey"))
4. 文本前后需要加上双引号.
   -- SubStr("I'm scripting, awesome!", 16)

MyVariable:=SubStr("I'm scripting, awesome!", 16)

这不是赋值的唯一方法，但这是最常用的. 通过将函数(这个例子中的函数是 SubStr(...))的内容写在:=右边这种方式，将函数的返回值分配给变量 MyVariable.
函数的更多信息

; 这些是命令
Msgbox, This is some text.
StringReplace, Output, Input, AutoHotKey, AutoHotkey, ALL
SendInput, This is awesome{!}{!}{!}

; 这些是函数
SubStr("I'm scripting, awesome!", 16)
FileExist(VariableContainingPath)
Output:=SubStr("I'm scripting, awesome!", 16)

if (var=5)
{
   MsgBox, var equals %var%!!
   Exitapp
}

if (var=5)
   MsgBox, var equals %var%!!
   Exitapp

if (var=5)
   MsgBox, var equals %var%!!
MsgBox, We are now 'outside' the if. We did not need {}'s since there was only 1 line below it.

1. variable=text
   
   这是给变量赋值最简单的方法，也是传统的赋值方法. 只需要在等号后面输入文本就行了.
2. variable=%variable2%
   
   更上面的方法类似，只是你将一个变量所对应的值赋给了另一个变量.
3. variable:="text"
   
   这里通过一个表达式给变量赋值，因为 = 前面有一个 :. 不过文本前后需要加上双引号.
4. variable:=variable2
   
   如果用表达式的方法赋值，变量不需要使用%.
5. variable:=6+8/3*2-sqrt(9)
   
   你还可以在表达式中使用运算.

1. 当你使用命令时（见前文），需要使用百分号.
   -- 输入变量和输出变量除外.
2. 当你使用传统模式（等号前面没有其它符号）给一个变量赋值时，需要使用百分号.

1. 参数中的输入或输出变量，不要使用百分号，例如: StringLen, OutputVar, InputVar
2. 赋值时左边的变量，不要使用百分号，例如: Var = 123abc
3. 在If语句中，传统赋值方式（不包括表达式）中左边的变量，不要使用百分号: If Var1 < %Var2%
4. 在表达式中的变量，不要使用百分号:

   If (Var1 != Var2)
      Var1 := Var2 + 100
   

InputBox, OutputVar, Question 1, What is your first name?
if (OutputVar="Bill")
   MsgBox, That's is an awesome name, %OutputVar%.

InputBox, OutputVar2, Question 2, Do you like AutoHotkey?
if (OutputVar2="yes")
   MsgBox, Thank you for answering %OutputVar2%`, %OutputVar%! We will become great friends.
else
   MsgBox, %OutputVar%`, That makes me sad.

MsgBox, 4, , Would you like to continue?
IfMsgBox, No
   Return                ; 如果选择No, 脚本将会终止.
MsgBox You pressed YES.  ; 用户选择了YES.

; 下面一些例子展示了什么时候该使用百分号，什么时候不该.
Variable=text                      ; 采用"传统"方式将一个文本赋值给一个变量.
VariableNumber:=6                  ; 采用"表达式"方式将一个数字赋值给一个变量.
Variable2=%Variable%               ; 采用"传统"方式将一个变量的值赋值给一个变量.
Variable3:=Variable                ; 采用"表达式"方式将一个变量的值赋值给一个变量.
Variable4.=Variable                ; 采用"表达式"方式将一个变量的值添加到另一个变量的后面.
Variable5+=VariableNumber          ; 采用"表达式"方式，将两个变量的值相加，然后把结果保存到第一个变量中.
Variable5-=VariableNumber          ; 采用"表达式"方式，将第一个变量的值减去第二个变量的，然后把结果保存到第一个变量中.
Variable6:=SubStr(Variable, 2, 2)  ; 在函数中的变量. 它们永远都是表达式.
Variable7=%Variable% Text          ; 采用"传统"方式，将一个变量的值加上一个文本然后赋值给另一个变量.
Variable8:=Variable " Text"        ; 采用"表达式"方式，将一个变量的值加上一个文本然后赋值给另一个变量.
MsgBox, %Variable%                 ; 在命令中的变量. 
StringSplit, Variable, Variable, x ; 在命令中的变量，但是它们作为输入或输出变量.
if (VariableNumber=6)              ; 如果IF采用括号的方式，那么括号中的内容就是一个表达式，所以不需要百分号.
If (Variable != VariableNumber)    ; 如果IF采用括号的方式，那么括号中的内容就是一个表达式，所以不需要百分号.
if VariableNumber=6                ; 如果IF不使用括号，那么IF后面的内容将采用传统方式. 不过，只有赋值语句"右边"的变量需要百分号. 
If Var1 < %Var2%                   ; 如果IF不使用括号，那么IF后面的内容将采用传统方式. 不过，只有赋值语句"右边"的变量需要百分号. 

1. 当你需要描述一组有序列表时，比如杂货店列表(这种情况最好使用索引数组)
2. 当你需要描述一个图形方格时，比如一个棋盘游戏(这种情况最好使用嵌套对象)
3. 当你需要描述一组事物而每样事物都有自己的名字时，比如描述水果的特性(这种情况最好使用关联数组)

1. MyObject := ["one", "two", "three", 17]
   
   采用方括号语法. 我们这里介绍所谓的"索引数组"对象. 索引数组表示这个对象包含一组数据，这些数据的索引号从1开始连续递增. 在这个例子中，值 "one" 对应键 1 (又叫做索引号1), 值 17 对应键 4 (又叫做索引号4).
2. Banana := {"Shape": "Elongated", "Color": "Yellow", "Taste": "Delicious", "Price": 3}
   
   采用花括号语法. 这里介绍所谓的"关联数组"对象. 关联数组表示这个对象包括一组数据，每个数据都自己的名字. 在这个例子中，值 "yellow" 对应键 "color". 同样的, 值 3 对应键 "Price".
3. MyObject := Array("one", "two", "three", 17)
   
   采用"数组"创建函数.这种方式跟方括号语法一样，区别仅仅是采用了函数的形式.
4. Banana := Object("Shape", "Elongated", "Color", "Yellow", "Taste", "Delicious", "Price", 3)
   
   采用对象创建函数.这种方式跟花括号语法一样，区别仅仅是采用了函数的形式.

1. Value := Banana["Color"]
   
   方括号语法. 允许你使用表达式作为键来获取对象的值. 在这个例子中，我仅仅使用表达式 "Color", 其他它就是键 Color， 我们将会得到一个值 "Yellow" , 因为我们将键 Color 与 "Yellow" 关联起来了，可以查看前面一节.
2. Value := Banana.Color
   
   句点语法. 仅仅允许使用文字串作为键名. 在句点语法中键不能使用变量.

1. 直接新增值
   想要直接新增一对键和值，只需要设置一个跟现有的键名不一样的新键就行了. 例如:
   MyObject.NewKey := "Shiny"
MyObject["NewerKey"] := 3.1415
2. 插入值
   其他新增键值到对象的方法是使用以下方法之一.
   
   MyObject.InsertAt(Index, Value1, Value2, Value3...)
   Index 为任意整数键. 这样将导致所有较高的整数键的索引增加插入值的数量, 即使是空缺的也一样(例如, 假设只有键 1 和 100 存在, 当插入一个值到第50个键的位置时, 将导致原来位于100的键的索引变成101).
   
   MyObject.Push(Value1, Value2, Value3...)
   "追加" 值到 MyObject 数组的尾部. 换句话说, 它将插入的值放在最高整数键加一的位置.
   

1. 用空白填充值.
   
   最简单的删除值的方法就是填充为空. 你可以将其赋值为 "" (两个连续的双引号), 也就是常说的 空字符串. 这不会删除键, 但它会将键设为类似从未赋值一样.
   可以通过使用 HasKey 方法得知键依然存在, 而且键也会出现在 for 循环中. (我们一会再解释for循环)
2. 移除键
   
   有几种同时删除键 和 值的办法,它们是:
   1. RemovedValue := MyObject.Delete(AnyKey)
      之前位于MyObject[AnyKey]的值将储存到 RemovedValue.
   2. NumberOfRemovedKeys := MyObject.Delete(FirstKey, LastKey)
      如果你使用这种形式，将删除一组连续的键和对应的值，范围从FirstKey开始，到LastKey结束.
      
      然后将删除的数量返回给变量NumberOfRemovedKeys. 当键与键之间有空隙，返回值就很有用，因为它可以告诉我们究竟删除了几个键.(比如，你想要删除一组键，从1到4，但其实这一组键中缺少键2，所以你一共只删除了3个键，那么NumberOfRemovedKeys的值就是3)
   3. MyObject.Pop()
      这种形式将删除最大的整数键，同时返回这个键对应的值. 而且这种形式不会影响其它键的索引顺序.
   4. RemovedValue := MyObject.RemoveAt(Index)
NumberOfRemovedKeys := MyObject.RemoveAt(Index, Length)
      这样将会移除从 Index 到 Index + Length - 1 (包含) 之间的所有键. 如果 Length 省略则默认值为 1 . 移除这些键之后,更高 数字或整数的键将向下填充空缺, 所以,如果有个值位于 Index + Length 那么它现在的位置就是 Index. 这很像 InsertAt 方法操作多个指定值的操作.

请注意，你不能忽略参数，只是需要将它们的位置留空.
如果你像下面这样忽略"WinTitle, WinText"，将会产生错误:
ControlGetText, OutputVar, Control, ExcludeTitle
语句非法.
ControlGetText, OutputVar, Control,,, ExcludeTitle

MsgBox, %A_AHKVersion%

if (car="old")
{
msgbox, the car is really old
if (wheels="flat")
{
msgbox, this car is not safe to drive.
Return
}
else
{
msgbox, Be careful! This old car will be dangerous to drive.
}
}
else
{
msgbox, My`, what a shiny new vehicle you have there.
}

if (car="old")
{
   msgbox, the car is really old
   if (wheels="flat")
   {
      msgbox, this car is not safe to drive.
      Return
   }
   else
   {
      msgbox, Be careful! This old car will be dangerous to drive.
   }
}
else
{
   msgbox, My`, what a shiny new vehicle you have there.
}